@tool
extends Node2D

signal player_entered

@export var one_shot := true
@export var freeze_time := 5.0
@export var hook_animation = ""
@export var lock_player_on_playing_dialogue = true
@export_enum("c01", "c02") var hook_dialogue_res = "c01":
	set(val):
		hook_dialogue_res = val
		match val:
			"c01":
				dialogue_res = dialogue_c01
			"c02":
				dialogue_res = dialogue_c02
		if is_node_ready():
			notify_property_list_changed()
var hook_dialogue_title = ""

var dialogue_c01 = preload("res://asset/dialogue/c01.dialogue")
var dialogue_c02 = preload("res://asset/dialogue/c02.dialogue")
var dialogue_res = dialogue_c01

var played_time := 0.0
# var played := false:
# 	set(val):
# 		if played != val and ground_archive:
# 			ground_archive.set_pair(name, "played", played)
# 		played = val

@onready var area2d = %Area2D as Area2D
@onready var ground_archive := ArchiveManager.archive.ground_archive()
@onready var played = ground_archive.get_value(name, "played", false):
	set(val):
		played = val
		ground_archive.set_pair(name, "played", played)


# Called when the node enters the scene tree for the first time.
func _ready() -> void:
	if Engine.is_editor_hint():
		return
	if one_shot and played:
		if GlobalConfig.DEBUG:
			print("Ambush already played, name=", name)
		return
	area2d.body_entered.connect(_entered)


func _entered(_body):
	var time = Time.get_ticks_msec()
	if not one_shot:
		var time_left = freeze_time - (time - played_time) * 0.001
		if time_left > 0:
			if GlobalConfig.DEBUG:
				print("Ambush freeze time not reached, time left=", time_left)
			return
	elif played:
		return
	played_time = time
	played = true
	# hook_animation
	if hook_animation:
		$AnimationPlayer.play(hook_animation)
	# hook_dialogue
	if hook_dialogue_title:
		if lock_player_on_playing_dialogue:
			SceneManager.freeze_player(0.0, "")
		DialogueManager.show_dialogue_balloon(dialogue_res, hook_dialogue_title)
		DialogueManager.dialogue_ended.connect(_on_dialogue_ended, CONNECT_ONE_SHOT)
	player_entered.emit()
	if GlobalConfig.DEBUG:
		print("ambush body_entered!")


func _on_dialogue_ended(_res):
	if GlobalConfig.DEBUG:
		print("Ambush dialogue ended")
	if lock_player_on_playing_dialogue:
		SceneManager.release_player()


func _get(property: StringName) -> Variant:
	if property == "hook_dialogue_title":
		return hook_dialogue_title
	return null


func _set(property: StringName, value: Variant) -> bool:
	if property == "hook_dialogue_title":
		hook_dialogue_title = value
		return true
	return false


func _get_property_list() -> Array[Dictionary]:
	return [
		{
			"name": "hook_dialogue_title",
			"type": TYPE_STRING,
			"hint": PROPERTY_HINT_ENUM_SUGGESTION,
			"hint_string": ",".join(dialogue_res.get_ordered_titles())
		}
	]