extends Control
class_name ContentInspector

signal display_toggled(displaying: bool)

@onready var label = $TipContainer/Label as Label

var tip_can_show = "Q: " + tr("ui_退出") + "     " + "E: " + tr("ui_阅读")
var tip_can_hide = "Q: " + tr("ui_退出") + "     " + "E: " + tr("ui_收起")

var displaying := false

var blinking_tween: Tween


func _ready() -> void:
	# tween tips
	blinking_tween = create_tween()
	blinking_tween.tween_property(label, "modulate:a", 0.8, 2.0)
	blinking_tween.tween_property(label, "modulate:a", 1.0, 2.0)
	blinking_tween.set_loops(-1)
	setup_display()


func setup_display(display := displaying):
	displaying = display
	for c in get_children():
		if c.name == "TipContainer":
			continue
		c.set("visible", displaying)
	# reset_tips
	if displaying:
		label.text = tip_can_hide
	else:
		label.text = tip_can_show


func _unhandled_input(event: InputEvent) -> void:
	if not is_visible_in_tree():
		return
	if event.is_action_pressed("interact"):
		get_viewport().set_input_as_handled()
		displaying = not displaying
		if displaying:
			$"Sfx显示".play()
		else:
			$"Sfx收起".play()
		setup_display()
		display_toggled.emit(displaying)