xiandie/manager/event_manager/event2d.gd

@tool
extends Node2D
class_name Event2D

# 当前事件
@export_group("event")
@export var event_name: StringName
@export_enum("none", "show", "hide") var event_mode := "show"
@export var event_stages: Array[int] = []
# 前置依赖事件，为空时意味着无前置事件
@export_group("pre_event")
@export var pre_event_name: StringName
@export_enum("none", "show", "hide") var pre_event_mode := "show"
@export var pre_event_stages: Array[int] = []
@export_tool_button("创建脚本") var create_script = _create_script
@export_tool_button("复制 greater setter") var copy_greater_setter = _copy_greater_setter
@export_tool_button("复制 setter") var copy_setter = _copy_setter
@export_tool_button("复制 getter") var copy_getter = _copy_getter

var prev_stage := 0
var stage := 0


func _ready() -> void:
	# if event_name != &"":
	# 	name = "Event_" + event_name
	if Engine.is_editor_hint():
		return
	if event_name != "":
		stage = EventManager.get_stage(event_name)
	if pre_event_name != "":
		prev_stage = EventManager.get_stage(pre_event_name)
	refresh_visibility()
	SceneManager.ground_ready.connect(_on_ground_ready)
	EventManager.stage_updated.connect(_on_global_stage_updated)


# 前置允许显示了，后续才可以显示
func refresh_visibility() -> void:
	var should_show = true
	if pre_event_name != &"" and pre_event_mode != "none":
		should_show = prev_stage in pre_event_stages
		if pre_event_mode == "hide":
			should_show = !should_show
	if should_show and event_name != &"" and event_mode != "none":
		should_show = stage in event_stages
		if event_mode == "hide":
			should_show = !should_show
	if visible != should_show:
		visible = should_show


func _on_global_stage_updated(e: StringName, s: int):
	var updated = false
	var pre_updated = false
	if e == pre_event_name:
		pre_updated = prev_stage != s
		prev_stage = s
		print(
			"[Event2D] Pre-event_name stage updated: %s, stage: %s" % [pre_event_name, prev_stage]
		)
	elif e == event_name:
		updated = stage != s
		stage = s
		print("[Event2D] Event stage updated: %s, stage: %s" % [event_name, stage])
	refresh_visibility()
	if pre_updated:
		_on_pre_stage_updated()
	if updated:
		_on_stage_updated()


func _on_ground_ready(ground: Ground2D):
	pass


func _on_pre_stage_updated():
	pass


func _on_stage_updated():
	pass


###### TOOL BUTTON

var script_template = preload("uid://bmxsei74o3pyw") as Script
var script_root_dir = "res://scene/ground/script/"


func _create_script():
	var script = script_template.duplicate(true) as Script
	var ground = get_node("..")
	while ground and not ground is Ground2D:
		ground = ground.get_node("..")
	if not ground:
		printerr("[Event2D] _create_script Ground2D not found.")
		return
	var chapter = ground.scene_name.substr(0, 3)
	var section = ground.scene_name.substr(4, 3)
	if len(chapter) != 3 or len(section) != 3:
		printerr("[Event2D] ground scene_name error: %s" % ground.scene_name)
		return
	var file_name = section + "_" + name.to_snake_case() + ".gd"
	var path = script_root_dir + chapter + "/" + file_name
	if FileAccess.file_exists(path):
		print("file exists, reattach the script to node: %s" % path)
		set_script(load(path))
		return
	ResourceSaver.save(script, path)
	set_script(load(path))
	print("[Event2D] Script created: %s" % path)


func _copy_greater_setter():
	var text = 'EventManager.set_stage_if_greater(&"%s", 1)' % event_name
	DisplayServer.clipboard_set(text)
	print("Copied event greater setter: %s" % text)


func _copy_setter():
	var text = 'EventManager.set_stage(&"%s", 1)' % event_name
	DisplayServer.clipboard_set(text)
	print("Copied event setter: %s" % text)


func _copy_getter():
	var text = 'EventManager.get_stage(&"%s")' % event_name
	DisplayServer.clipboard_set(text)
	print("Copied event getter: %s" % text)